home *** CD-ROM | disk | FTP | other *** search
/ FM Towns: Free Software Collection 7 / FM Towns Free Software Collection 7.iso / fb386 / han84 / han84.bas next >
BASIC Source File  |  1993-11-30  |  17KB  |  433 lines
  1. 100 ' 
  2. 110 '       阪急は84駅  (v1.0) メインプログラム
  3. 120 '                                by Haruo Tamura 
  4. 130 '              FILE "HAN84MAP.BAS"
  5. 140 ' 
  6. 150 CLS:SCREEN@0:DEF PEN 0,2
  7. 160 DIM EKI$(100),C(100)
  8. 170 RESTORE *データ :FOR N=1 TO 84:READ DUMM, EKI$(N),C(N):NEXT
  9. 180 *色設定  ' [  G,  R,  B] 
  10. 190 PALETTE 0, [  0,  0,  0]  ' ブラック
  11. 200 PALETTE 1, [240,240,192]  ' イエロー
  12. 210 PALETTE 2, [128,240,224]  ' ピンク
  13. 220 PALETTE 3, [240,176,176]  ' グリーン
  14. 230 PALETTE 4, [240,160,240]  ' ブルー
  15. 240 PALETTE 5, [208,208,240]  ' パープル
  16. 250 PALETTE 6, [248,200,240]  ' 淡ブルー
  17. 260 PALETTE 7, [200,248,248]  ' 淡ピンク
  18. 270 PALETTE 8, [160, 40,240]  ' ブルー2
  19. 280 PALETTE 9, [240,104,104]  ' グリーン2
  20. 290 PALETTE 10,[200,240, 80]  ' オレンジ
  21. 300 PALETTE 11,[248,248,216]  ' クリームイエロー
  22. 310 PALETTE 12,[255,255,255]  ' 白
  23. 320 COLOR 1,0,0
  24. 330 '
  25. 340 *メイン
  26. 350 LOAD@ "HAN84MAP.TIF" : MOUSE 0:MOUSE 1,320,240,1
  27. 360 '乗車駅指定
  28. 370 LINE (402,400)-(632,476),PSET,%6,BF
  29. 380 SYMBOL (410,404), "乗車駅を指定",2,2,,,,1,1
  30. 390 SYMBOL (465,440), "して下さい  ",2,2,,,,1,1
  31. 400   IF MOUSE (2,0)<>-1 THEN GOTO 400
  32. 410   MX=MOUSE(0):MY=MOUSE(1)
  33. 420   IF MOUSE (2,0)<>0 THEN GOTO 410
  34. 430   GOSUB *判別 :IF STN=0 THEN GOTO 400
  35. 440   LINE (10+35*MXX,47+35*MYY)-(36+35*MXX,73+35*MYY),XOR,%3,BF
  36. 450   STN1=STN
  37. 460 '下車駅指定
  38. 470 LINE (402,400)-(632,476),PSET,%6,BF
  39. 480 SYMBOL (410,404), "下車駅を指定",2,2,,,,1,1
  40. 490 SYMBOL (465,440), "して下さい  ",2,2,,,,1,1
  41. 500   IF MOUSE (2,0)<>-1 THEN GOTO 500
  42. 510   MX=MOUSE(0):MY=MOUSE(1)
  43. 520   IF MOUSE (2,0)<>0 THEN GOTO 510
  44. 530   GOSUB *判別 : IF STN=0 THEN GOTO 500
  45. 540   LINE (10+35*MXX,47+35*MYY)-(36+35*MXX,73+35*MYY),XOR,%3,BF
  46. 550   STN2=STN:IF STN2=STN1 THEN GOTO *メイン
  47. 560  GOSUB *距離:GOSUB *表示
  48. 570 LINE (402,400)-(632,476),PSET,%6,BF
  49. 580 SYMBOL (410,404), "続けて計算しますか?",1,1,,,,1,1
  50. 590  LINE (412,424)-(473,451),PSET,%0,B
  51. 600  LINE (489,424)-(550,451),PSET,%0,B
  52. 610 SYMBOL (410,430), " 続ける   終わる",1,1,,,,1,1
  53. 620   IF MOUSE (2,0)<>-1 THEN GOTO 620
  54. 630   MX=MOUSE(0):MY=MOUSE(1)
  55. 640   GOSUB *判別2 : IF HANTEI=0 THEN GOTO 570
  56. 650  IF HANTEI=1 THEN MOUSE 0:GOTO *メイン
  57. 660  IF HANTEI=2 THEN MOUSE 0:END
  58. 670 *判別 :STN=1
  59. 680  MMX!=(MX-8)/35:MMY!=(MY-45)/35
  60. 690  MXX=(MX-8)\35 :MYY=(MY-45)\35
  61. 700   IF (MMX-MXX)<0 OR (MMX-MXX)>.85! THEN STN=0
  62. 710   IF (MMY-MYY)<0 OR (MMY-MYY)>.85! THEN STN=0
  63. 720   IF MXX<0 OR MXX>17 THEN STN=0
  64. 730   IF MYY<0 OR MYY>11 THEN STN=0 
  65. 740  IF STN=0 THEN GOTO 1600 
  66. 750  X=MXX:Y=MYY:STN=0
  67. 760   IF X=7  AND Y=11 THEN STN=1
  68. 770   IF X=7  AND Y=10 THEN STN=2
  69. 780   IF X=7  AND Y=9  THEN STN=3
  70. 790   IF X=6  AND Y=9  THEN STN=4
  71. 800   IF X=5  AND Y=9  THEN STN=5
  72. 810   IF X=4  AND Y=9  THEN STN=6
  73. 820   IF X=3  AND Y=9  THEN STN=7
  74. 830   IF X=2  AND Y=9  THEN STN=8
  75. 840   IF X=1  AND Y=9  THEN STN=9
  76. 850   IF X=0  AND Y=9  THEN STN=10
  77. 860   IF X=0  AND Y=8  THEN STN=11
  78. 870   IF X=0  AND Y=7  THEN STN=12
  79. 880   IF X=0  AND Y=6  THEN STN=13
  80. 890   IF X=0  AND Y=5  THEN STN=14
  81. 900   IF X=0  AND Y=4  THEN STN=15
  82. 910   IF X=0  AND Y=3  THEN STN=16
  83. 920   IF X=4  AND Y=8  THEN STN=17
  84. 930   IF X=4  AND Y=7  THEN STN=18
  85. 940   IF X=4  AND Y=6  THEN STN=19
  86. 950   IF X=2  AND Y=10 THEN STN=20
  87. 960   IF X=2  AND Y=11 THEN STN=21
  88. 970   IF X=2  AND Y=8  THEN STN=22
  89. 980   IF X=2  AND Y=7  THEN STN=23
  90. 990   IF X=2  AND Y=6  THEN STN=24
  91. 1000   IF X=2  AND Y=5  THEN STN=25
  92. 1010   IF X=2  AND Y=4  THEN STN=26
  93. 1020   IF X=2  AND Y=3  THEN STN=27
  94. 1030   IF X=2  AND Y=2  THEN STN=28
  95. 1040   IF X=1  AND Y=8  THEN STN=29
  96. 1050   IF X=1  AND Y=7  THEN STN=30
  97. 1060   IF X=7  AND Y=8  THEN STN=31
  98. 1070   IF X=7  AND Y=7  THEN STN=32
  99. 1080   IF X=7  AND Y=6  THEN STN=33
  100. 1090   IF X=7  AND Y=5  THEN STN=34
  101. 1100   IF X=7  AND Y=4  THEN STN=35
  102. 1110   IF X=7  AND Y=3  THEN STN=36
  103. 1120   IF X=7  AND Y=2  THEN STN=37
  104. 1130   IF X=7  AND Y=1  THEN STN=38
  105. 1140   IF X=7  AND Y=0  THEN STN=39
  106. 1150   IF X=6  AND Y=0  THEN STN=40
  107. 1160   IF X=5  AND Y=0  THEN STN=41
  108. 1170   IF X=4  AND Y=0  THEN STN=42
  109. 1180   IF X=3  AND Y=0  THEN STN=43
  110. 1190   IF X=2  AND Y=0  THEN STN=44
  111. 1200   IF X=2  AND Y=1  THEN STN=45
  112. 1210   IF X=8  AND Y=1  THEN STN=46
  113. 1220   IF X=8  AND Y=2  THEN STN=47
  114. 1230   IF X=8  AND Y=3  THEN STN=48
  115. 1240   IF X=8  AND Y=9  THEN STN=49
  116. 1250   IF X=9  AND Y=9  THEN STN=40
  117. 1260   IF X=10 AND Y=9  THEN STN=51
  118. 1270   IF X=11 AND Y=9  THEN STN=52
  119. 1280   IF X=12 AND Y=9  THEN STN=53
  120. 1290   IF X=13 AND Y=9  THEN STN=54
  121. 1300   IF X=14 AND Y=9  THEN STN=55
  122. 1310   IF X=15 AND Y=9  THEN STN=56
  123. 1320   IF X=16 AND Y=9  THEN STN=57
  124. 1330   IF X=17 AND Y=9  THEN STN=58
  125. 1340   IF X=17 AND Y=8  THEN STN=59
  126. 1350   IF X=17 AND Y=7  THEN STN=60
  127. 1360   IF X=17 AND Y=6  THEN STN=61
  128. 1370   IF X=17 AND Y=5  THEN STN=62
  129. 1380   IF X=17 AND Y=4  THEN STN=63
  130. 1390   IF X=17 AND Y=3  THEN STN=64
  131. 1400   IF X=17 AND Y=2  THEN STN=65
  132. 1410   IF X=17 AND Y=1  THEN STN=66
  133. 1420   IF X=17 AND Y=0  THEN STN=67
  134. 1430   IF X=16 AND Y=0  THEN STN=68
  135. 1440   IF X=15 AND Y=0  THEN STN=69
  136. 1450   IF X=14 AND Y=0  THEN STN=70
  137. 1460   IF X=13 AND Y=0  THEN STN=71
  138. 1470   IF X=10 AND Y=10 THEN STN=72
  139. 1480   IF X=10 AND Y=11 THEN STN=73
  140. 1490   IF X=10 AND Y=8  THEN STN=74
  141. 1500   IF X=10 AND Y=7  THEN STN=75
  142. 1510   IF X=10 AND Y=6  THEN STN=76
  143. 1520   IF X=10 AND Y=5  THEN STN=77
  144. 1530   IF X=10 AND Y=4  THEN STN=78
  145. 1540   IF X=10 AND Y=3  THEN STN=79
  146. 1550   IF X=10 AND Y=2  THEN STN=80
  147. 1560   IF X=10 AND Y=1  THEN STN=81
  148. 1570   IF X=16 AND Y=1  THEN STN=82
  149. 1580   IF X=15 AND Y=1  THEN STN=83
  150. 1590   IF X=14 AND Y=1  THEN STN=84
  151. 1600 RETURN
  152. 1610 *判別2 :HANTEI=0
  153. 1620  IF MY>=424 AND MY=<451 AND MX>=412 AND MX=<473 THEN HANTEI=1
  154. 1630  IF MY>=424 AND MY=<451 AND MX>=489 AND MX=<550 THEN HANTEI=2
  155. 1640  RETURN
  156. 1650 *距離
  157. 1660  IF STN1<1 OR STN1>84 OR STN2<1 OR STN2>84 THEN END
  158. 1670  IF STN1<STN2 THEN S1=STN1 :S2=STN2
  159. 1680  IF STN1>STN2 THEN S1=STN2:S2=STN1
  160. 1690   IF S1=1 OR S1=2 OR S1=3 THEN ｷｮﾘ=C(S2)-C(S1)
  161. 1700   IF S1=4 THEN 
  162. 1710     IF S2=<30            THEN ｷｮﾘ=C(S2)-C(S1) 
  163. 1720     IF S2>=31 AND S2=<43 THEN ｷｮﾘ=C(S2)-.7!
  164. 1730     IF S2=44 OR S2=45    THEN ｷｮﾘ=43.8!-C(S2) 
  165. 1740     IF S2>=46            THEN ｷｮﾘ=C(S2)-.7!
  166. 1750    ENDIF
  167. 1760   IF S1=5 THEN 
  168. 1770     IF S2=<30            THEN ｷｮﾘ=C(S2)-C(S1) 
  169. 1780     IF S2>=31 AND S2=<41 THEN ｷｮﾘ=C(S2)+2.4!
  170. 1790     IF S2>=42 AND S2=<45 THEN ｷｮﾘ=40.7!-C(S2) 
  171. 1800     IF S2>=46            THEN ｷｮﾘ=C(S2)+2.4!
  172. 1810    ENDIF
  173. 1820   IF S1=6 THEN 
  174. 1830     IF S2=<30            THEN ｷｮﾘ=C(S2)-C(S1) 
  175. 1840     IF S2>=31 AND S2=<39 THEN ｷｮﾘ=C(S2)+5.4!
  176. 1850     IF S2>=40 AND S2=<45 THEN ｷｮﾘ=37.7!-C(S2) 
  177. 1860     IF S2>=46            THEN ｷｮﾘ=C(S2)+5.4!
  178. 1870    ENDIF
  179. 1880   IF S1=7 THEN 
  180. 1890     IF S2=<30            THEN ｷｮﾘ=C(S2)-C(S1) 
  181. 1900     IF S2>=31 AND S2=<38 THEN ｷｮﾘ=C(S2)+7.5!
  182. 1910     IF S2>=39 AND S2=<45 THEN ｷｮﾘ=35.6!-C(S2) 
  183. 1920     IF S2>=46            THEN ｷｮﾘ=C(S2)+7.5!
  184. 1930    ENDIF
  185. 1940   IF S1=8 THEN 
  186. 1950     IF S2=<30            THEN ｷｮﾘ=C(S2)-C(S1) 
  187. 1960     IF S2>=31 AND S2=<36 THEN ｷｮﾘ=C(S2)+10.8!
  188. 1970     IF S2>=37 AND S2=<45 THEN ｷｮﾘ=32.3!-C(S2) 
  189. 1980     IF S2>=46 AND S2=<48 THEN ｷｮﾘ=C(S2)+5.1!
  190. 1990     IF S2>=49            THEN ｷｮﾘ=C(S2)+10.8!
  191. 2000    ENDIF
  192. 2010   IF S1>=9 AND S1=<16 THEN 
  193. 2020     IF S2=<16            THEN ｷｮﾘ=C(S2)-C(S1) 
  194. 2030     IF S2>=17 AND S2=<19 THEN ｷｮﾘ=C(S1)+C(S2)-20.4!
  195. 2040     IF S2>=20 AND S2=<28 THEN ｷｮﾘ=C(S1)+C(S2)-31.2!
  196. 2050     IF S2=29 OR S2=30    THEN ｷｮﾘ=C(S1)+C(S2)-36.6! 
  197. 2060     IF S2>=31 AND S2=<36 THEN ｷｮﾘ=C(S1)+C(S2)-4.8!
  198. 2070     IF S2>=37 AND S2=<45 THEN ｷｮﾘ=C(S1)+16.7!-C(S2) 
  199. 2080     IF S2>=46 AND S2=<48 THEN ｷｮﾘ=C(S1)+C(S2)-10.5!
  200. 2090     IF S2>=49            THEN ｷｮﾘ=C(S1)+C(S2)-4.8!
  201. 2100    ENDIF
  202. 2110   IF S1>=17 AND S1=<19 THEN
  203. 2120     IF S2=<30            THEN ｷｮﾘ=C(S1)+C(S2)-20.4! 
  204. 2130     IF S2>=31 AND S2=<39 THEN ｷｮﾘ=C(S1)+C(S2)-4.8!
  205. 2140     IF S2>=40 AND S2=<45 THEN ｷｮﾘ=C(S1)+27.5!-C(S2) 
  206. 2150     IF S2>=46            THEN ｷｮﾘ=C(S1)+C(S2)-4.8!
  207. 2160    ENDIF
  208. 2170   IF S1>=20 AND S1=<21 THEN
  209. 2180     IF S2=<30            THEN ｷｮﾘ=C(S1)+C(S2)-31.2! 
  210. 2190     IF S2>=31 AND S2=<36 THEN ｷｮﾘ=C(S1)+C(S2)-4.8!
  211. 2200     IF S2>=37 AND S2=<45 THEN ｷｮﾘ=C(S1)+16.7!-C(S2) 
  212. 2210     IF S2>=46 AND S2=<48 THEN ｷｮﾘ=C(S1)+C(S2)-10.5!
  213. 2220     IF S2>=49            THEN ｷｮﾘ=C(S1)+C(S2)-4.8!
  214. 2230    ENDIF
  215. 2240   IF S1=22 THEN
  216. 2250     IF S2=<28            THEN ｷｮﾘ=C(S2)-C(S1)
  217. 2260     IF S2>=29 AND S2=<30 THEN ｷｮﾘ=C(S1)+C(S2)-31.2! 
  218. 2270     IF S2>=31 AND S2=<34 THEN ｷｮﾘ=C(S1)+C(S2)-4.8!
  219. 2280     IF S2>=35 AND S2=<45 THEN ｷｮﾘ=C(S1)+14.1!-C(S2) 
  220. 2290     IF S2>=46 AND S2=<48 THEN ｷｮﾘ=C(S1)+C(S2)-13.1!
  221. 2300     IF S2>=49            THEN ｷｮﾘ=C(S1)+C(S2)-4.8!
  222. 2310    ENDIF
  223. 2320   IF S1>=23 AND S1=<24 THEN
  224. 2330     IF S2=<28            THEN ｷｮﾘ=C(S2)-C(S1)
  225. 2340     IF S2>=29 AND S2=<30 THEN ｷｮﾘ=C(S1)+C(S2)-31.2! 
  226. 2350     IF S2>=31 AND S2=<33 THEN ｷｮﾘ=C(S1)+C(S2)-4.8!
  227. 2360     IF S2>=34 AND S2=<45 THEN ｷｮﾘ=47.9!-C(S1)-C(S2) 
  228. 2370     IF S2>=46 AND S2=<48 THEN ｷｮﾘ=C(S2)-C(S1)+20.7!
  229. 2380     IF S2>=49            THEN ｷｮﾘ=C(S1)+C(S2)-4.8!
  230. 2390    ENDIF
  231. 2400   IF S1>=25 AND S1=<26 THEN
  232. 2410     IF S2=<28            THEN ｷｮﾘ=C(S2)-C(S1)
  233. 2420     IF S2>=29 AND S2=<30 THEN ｷｮﾘ=C(S1)+C(S2)-31.2! 
  234. 2430     IF S2=31             THEN ｷｮﾘ=C(S1)+C(S2)-4.8!
  235. 2440     IF S2>=32 AND S2=<45 THEN ｷｮﾘ=47.9!-C(S1)-C(S2) 
  236. 2450     IF S2>=46 AND S2=<48 THEN ｷｮﾘ=C(S2)-C(S1)+20.7!
  237. 2460     IF S2>=49            THEN ｷｮﾘ=C(S1)+C(S2)-4.8!
  238. 2470    ENDIF
  239. 2480   IF S1>=27 AND S1=<28 THEN
  240. 2490     IF S2=28             THEN ｷｮﾘ=C(S2)-C(S1)
  241. 2500     IF S2>=29 AND S2=<30 THEN ｷｮﾘ=C(S1)+C(S2)-31.2! 
  242. 2510     IF S2>=31 AND S2=<45 THEN ｷｮﾘ=47.9!-C(S1)-C(S2) 
  243. 2520     IF S2>=46 AND S2=<48 THEN ｷｮﾘ=C(S2)-C(S1)+20.7!
  244. 2530     IF S2>=49            THEN ｷｮﾘ=C(S1)+C(S2)-4.8!
  245. 2540    ENDIF
  246. 2550   IF S1>=29 AND S1=<30 THEN
  247. 2560     IF S2=30             THEN ｷｮﾘ=C(S2)-C(S1)
  248. 2570     IF S2>=31 AND S2=<36 THEN ｷｮﾘ=C(S1)+C(S2)-4.8!
  249. 2580     IF S2>=37 AND S2=<45 THEN ｷｮﾘ=C(S1)+16.7!-C(S2) 
  250. 2590     IF S2>=46 AND S2=<48 THEN ｷｮﾘ=C(S1)+C(S2)-10.5!
  251. 2600     IF S2>=49            THEN ｷｮﾘ=C(S1)+C(S2)-4.8!
  252. 2610    ENDIF
  253. 2620   IF S1>=31 AND S1=<38 THEN
  254. 2630     IF S2=<48            THEN ｷｮﾘ=C(S2)-C(S1)
  255. 2640     IF S2>=49            THEN ｷｮﾘ=C(S1)+C(S2)-4.8!
  256. 2650    ENDIF
  257. 2660   IF S1>=39 AND S1=<45 THEN
  258. 2670     IF S2=<45            THEN ｷｮﾘ=C(S2)-C(S1)
  259. 2680     IF S2>=46 AND S2=<48 THEN ｷｮﾘ=C(S1)+C(S2)-27.2!
  260. 2690     IF S2>=49            THEN ｷｮﾘ=C(S1)+C(S2)-4.8!
  261. 2700    ENDIF
  262. 2710   IF S1>=46 AND S1=<48 THEN
  263. 2720     IF S2=<48            THEN ｷｮﾘ=C(S2)-C(S1)
  264. 2730     IF S2>=49            THEN ｷｮﾘ=C(S1)+C(S2)-4.8!
  265. 2740    ENDIF
  266. 2750   IF S1>=49 AND S1=<51 THEN ｷｮﾘ=C(S2)-C(S1)
  267. 2760   IF S1>=52 AND S1=<66 THEN 
  268. 2770     IF S2=<71            THEN ｷｮﾘ=C(S2)-C(S1)
  269. 2780     IF S2>=72 AND S2=<81 THEN ｷｮﾘ=C(S1)+C(S2)-13.2!
  270. 2790     IF S2>=82            THEN ｷｮﾘ=C(S2)-C(S1)
  271. 2800    ENDIF
  272. 2810   IF S1>=67 AND S1=<71 THEN 
  273. 2820     IF S2=<71            THEN ｷｮﾘ=C(S2)-C(S1)
  274. 2830     IF S2>=72 AND S2=<81 THEN ｷｮﾘ=C(S1)+C(S2)-13.2!
  275. 2840     IF S2>=82            THEN ｷｮﾘ=C(S2)+C(S1)-80.8!
  276. 2850    ENDIF
  277. 2860   IF S1>=72 AND S1=<73 THEN 
  278. 2870     IF S2=73             THEN ｷｮﾘ=C(S2)-C(S1)
  279. 2880     IF S2>=74            THEN ｷｮﾘ=C(S1)+C(S2)-13.2!
  280. 2890    ENDIF
  281. 2900   IF S1>=74 AND S1=<81 THEN 
  282. 2910     IF S2=<81            THEN ｷｮﾘ=C(S2)-C(S1)
  283. 2920     IF S2>=82            THEN ｷｮﾘ=C(S1)+C(S2)-13.2!
  284. 2930    ENDIF
  285. 2940   IF S1>=82 AND S1=<84 THEN ｷｮﾘ=C(S2)-C(S1)
  286. 2950 *運賃
  287. 2960  KKK=INT(ｷｮﾘ-.01!)+1
  288. 2970   IF             KKK=<4  THEN OTONA=120
  289. 2980   IF KKK>=5  AND KKK=<9  THEN OTONA=160
  290. 2990   IF KKK>=10 AND KKK=<14 THEN OTONA=200
  291. 3000   IF KKK>=15 AND KKK=<19 THEN OTONA=230
  292. 3010   IF KKK>=19 AND KKK=<26 THEN OTONA=250
  293. 3020   IF KKK>=27 AND KKK=<33 THEN OTONA=280
  294. 3030   IF KKK>=34 AND KKK=<42 THEN OTONA=320
  295. 3040   IF KKK>=43 AND KKK=<51 THEN OTONA=350
  296. 3050   IF KKK>=52 AND KKK=<60 THEN OTONA=410
  297. 3060   IF KKK>=61 AND KKK=<70 THEN OTONA=470
  298. 3070   IF KKK>=71             THEN OTONA=560
  299. 3080  KODOMO=(OTONA+10)\20:KODOMO=KODOMO*10
  300. 3090   IF             KKK=<4  THEN TUKIN=KKK*400+2800
  301. 3100   IF KKK>=5  AND KKK=<8  THEN TUKIN=KKK*350+3000
  302. 3110   IF KKK>=9  AND KKK=<11 THEN TUKIN=KKK*300+3400
  303. 3120   IF KKK>=12 AND KKK=<15 THEN TUKIN=KKK*250+3950
  304. 3130   IF KKK>=16 AND KKK=<46 THEN TUKIN=KKK*200+4700
  305. 3140   IF KKK>=47 AND KKK=<55 THEN TUKIN=KKK*150+7000
  306. 3150   IF KKK>=56             THEN TUKIN=KKK*100+9750
  307. 3160    TUKIN3=INT(TUKIN*2.85!)+9:TUKIN3=TUKIN3\10:TUKIN3=TUKIN3*10
  308. 3170    TUKIN6=INT(TUKIN*5.4!)+9:TUKIN6=TUKIN6\10:TUKIN6=TUKIN6*10
  309. 3180 '
  310. 3190   IF             KKK=<4  THEN TUGAK=KKK*140+960
  311. 3200   IF KKK>=5  AND KKK=<9  THEN TUGAK=KKK*120+1040
  312. 3210   IF KKK>=10 AND KKK=<13 THEN TUGAK=KKK*100+1220
  313. 3220   IF KKK>=14 AND KKK=<18 THEN TUGAK=KKK*80 +1480
  314. 3230   IF KKK>=19 AND KKK=<26 THEN TUGAK=KKK*60 +1840
  315. 3240   IF KKK>=27 AND KKK=<35 THEN TUGAK=KKK*40 +2360
  316. 3250   IF KKK>=36 AND KKK=<52 THEN TUGAK=KKK*30 +2710
  317. 3260   IF KKK>=53             THEN TUGAK=KKK*20 +3230
  318. 3270    TUGAK3=INT(TUGAK*2.85!)+9:TUGAK3=TUGAK3\10:TUGAK3=TUGAK3*10
  319. 3280    TUGAK6=INT(TUGAK*5.4!)+9:TUGAK6=TUGAK6\10:TUGAK6=TUGAK6*10
  320. 3290  RETURN
  321. 3300 *データ
  322. 3310 DATA 1, 梅田,         0.0
  323. 3320 DATA 2, 中津,         0.9
  324. 3330 DATA 3, 十三,         2.4
  325. 3340 DATA 4, 神崎川,       4.1
  326. 3350 DATA 5, 園田,         7.2
  327. 3360 DATA 6, 塚口,        10.2
  328. 3370 DATA 7, 武庫之荘,    12.3
  329. 3380 DATA 8, 西宮北口,    15.6
  330. 3390 DATA 9, 夙川,        18.3
  331. 3400 DATA 10, 芦屋川,      21.0
  332. 3410 DATA 11, 岡本,        23.4
  333. 3420 DATA 12, 御影,        25.6
  334. 3430 DATA 13, 六甲,        27.4
  335. 3440 DATA 14, 王子公園,    29.2
  336. 3450 DATA 15, 春日野道,    30.7
  337. 3460 DATA 16, 三宮,        32.3
  338. 3470 DATA 17, 稲野,        11.6
  339. 3480 DATA 18, 新伊丹,      12.4
  340. 3490 DATA 19, 伊丹,        13.3
  341. 3500 DATA 20, 阪神国道,    16.5
  342. 3510 DATA 21, 今津,        17.2
  343. 3520 DATA 22, 門戸厄神,    16.9
  344. 3530 DATA 23, 甲東園,      17.9
  345. 3540 DATA 24, 仁川,        18.8
  346. 3550 DATA 25, 小林,        20.5
  347. 3560 DATA 26, 逆瀬川,      21.5
  348. 3570 DATA 27, 宝塚南口,    22.4
  349. 3580 DATA 28, 宝塚,        23.3
  350. 3590 DATA 29, 苦楽園口,    19.2
  351. 3600 DATA 30, 甲陽園,      20.5
  352. 3610 DATA 31, 三国,         4.5
  353. 3620 DATA 32, 庄内,         6.0
  354. 3630 DATA 33, 服部,         7.5
  355. 3640 DATA 34, 曽根,         8.7
  356. 3650 DATA 35, 岡町,         9.6
  357. 3660 DATA 36, 豊中,        10.6
  358. 3670 DATA 37, 蛍池,        12.0
  359. 3680 DATA 38, 石橋,        13.6
  360. 3690 DATA 39, 池田,        15.9
  361. 3700 DATA 40, 川西能勢口,  17.1
  362. 3710 DATA 41, 雲雀丘花屋敷,18.2
  363. 3720 DATA 42, 山本,        19.8
  364. 3730 DATA 43, 中山,        21.6
  365. 3740 DATA 44, 売布神社,    22.4
  366. 3750 DATA 45, 清荒神,      23.4
  367. 3760 DATA 46, 桜井,        15.2
  368. 3770 DATA 47, 牧落,        16.3
  369. 3780 DATA 48, 箕面,        17.6
  370. 3790 DATA 49, 南方,         4.3
  371. 3800 DATA 50, 崇禅寺,       5.6
  372. 3810 DATA 51, 淡路,         6.6
  373. 3820 DATA 52, 上新庄,       8.7
  374. 3830 DATA 53, 相川,         9.6
  375. 3840 DATA 54, 正雀,        11.8
  376. 3850 DATA 55, 南茨木,      15.3
  377. 3860 DATA 56, 茨木市,      17.2
  378. 3870 DATA 57, 総持寺,      18.6
  379. 3880 DATA 58, 富田,        19.7
  380. 3890 DATA 59, 高槻市,      23.0
  381. 3900 DATA 60, 上牧,        27.3
  382. 3910 DATA 61, 水無瀬,      28.1
  383. 3920 DATA 62, 大山崎,      30.1
  384. 3930 DATA 63, 長岡天神,    34.1
  385. 3940 DATA 64, 西向日,      36.0
  386. 3950 DATA 65, 東向日,      37.4
  387. 3960 DATA 66, 桂,          40.4
  388. 3970 DATA 67, 西京極,      42.5
  389. 3980 DATA 68, 西院,        44.3
  390. 3990 DATA 69, 大宮,        45.7
  391. 4000 DATA 70, 烏丸,        46.8
  392. 4010 DATA 71, 河原町,      47.7
  393. 4020 DATA 72, 柴島,         7.9
  394. 4030 DATA 73, 天神橋筋6,   10.1
  395. 4040 DATA 74, 下新庄,       7.5
  396. 4050 DATA 75, 吹田,         9.1
  397. 4060 DATA 76, 豊津,        10.0
  398. 4070 DATA 77, 関大前,      10.9
  399. 4080 DATA 78, 千里山,      11.7
  400. 4090 DATA 79, 南千里,      13.3
  401. 4100 DATA 80, 山田,        14.7
  402. 4110 DATA 81, 北千里,      16.7
  403. 4120 DATA 82, 上桂,        41.8
  404. 4130 DATA 83, 松尾,        43.2
  405. 4140 DATA 84, 嵐山,        44.5
  406. 4150 *表示
  407. 4160  SYMBOL (410,128),EKI$(STN1),1,1,,,,1,1
  408. 4170   EKI2$=" → "+EKI$(STN2)
  409. 4180  SYMBOL (440,146),EKI2$,1,1,,,,1,1
  410. 4190   K%=ｷｮﾘ*10:KK!=K%/10 
  411. 4200   IF K%<10 THEN K$="  0."+MID$(STR$(K%),2,1)
  412. 4210   IF K%>=10 AND K1<100 THEN K$=" "+STR$(KK!)
  413. 4220   IF K%>=100 THEN K$=STR$(KK!)
  414. 4230   IF K%=INT(KK!)*10 THEN K$=K$+".0"
  415. 4240   K$=" "+K$
  416. 4250  SYMBOL (497,170),K$,1,1,,,,1,1
  417. 4260   OTONA$=STR$(OTONA)
  418. 4270   KODOMO$=STR$(KODOMO)
  419. 4280   IF KODOMO<100 THEN KODOMO$=" "+STR$(KODOMO)
  420. 4290 SYMBOL (515,188), OTONA$,1,1,,,,1,1
  421. 4300 SYMBOL (515,206), KODOMO$,1,1,,,,1,1
  422. 4310 NN=TUKIN :GOSUB *数値:SYMBOL (488,230), NN$,1,1,,,,1,1
  423. 4320 NN=TUKIN3:GOSUB *数値:SYMBOL (488,248), NN$,1,1,,,,1,1
  424. 4330 NN=TUKIN6:GOSUB *数値:SYMBOL (488,266), NN$,1,1,,,,1,1
  425. 4340 NN=TUGAK :GOSUB *数値:SYMBOL (488,290), NN$,1,1,,,,1,1
  426. 4350 NN=TUGAK3:GOSUB *数値:SYMBOL (488,308), NN$,1,1,,,,1,1
  427. 4360 NN=TUGAK6:GOSUB *数値:SYMBOL (488,326), NN$,1,1,,,,1,1
  428. 4370 RETURN
  429. 4380 *数値
  430. 4390  IF NN>9999 THEN GOTO 4410
  431. 4400  NN$=" "+LEFT$(STR$(NN),2)+","+RIGHT$(STR$(NN),3) :RETURN
  432. 4410  NN$=    LEFT$(STR$(NN),3)+","+RIGHT$(STR$(NN),3) :RETURN
  433.